Name            I/O-24 Expansion Module ;
Partno          None ;
Revision        01 ;
Date            2/01/93 ;
Designer        Tom Bachmann ;
Company         Blue Earth Research ;
Assembly        None ;
Location        None ;
Device          P18CV8 ;        /*  AMI/GOULD PEEL18CV8  */


/************************************************************************/
/* This device generates chip select signals for the I/O expander.      */
/************************************************************************/

/** Inputs **/

Pin 1           = CLOCKIN ;             /* Register clock               */
Pin [2..9]      = [A8..15] ;            /* Address inputs A8 thru A15   */
Pin 11          = OEIN ;                /* Output enable input          */
Pin 13          = WR ;                  /*                              */

/** Outputs **/

Pin 12          = W_P_ ;                /* W.P. to Micro-440            */
Pin 14          = WPOUT ;               /* Write protect output         */
Pin 15          = RES ;                 /* Reset for 82C55              */
Pin 16          = !Chip ;               /* Chip select for 82C55        */
Pin 17          = A_1 ;                 /* 82C55 address                */
Pin 18          = A_0 ;                 /* 82C55 address                */
Pin 19          = CLOCKOUT ;            /* Decoded clock signal         */


/** Declarations and Intermediate Variable Definitions  **/

Field   Addr    = [A8..15] ;

/** Logic Equations **/

/*  Micro-440 peripheral map:   FF00H = ADC0848CCV A/D                  */
/*                              FE00H = RTC-72423B Clock                */

CLOCKOUT        = Addr:[E000..E300] & !WR ;
WPOUT.D         = A8 ;
WPOUT.AR        = OEIN ;
WPOUT.SP        = OEIN ;
RES.D           = A9 ;
RES.AR          = OEIN ;
RES.SP          = OEIN ;

W_P_            = WPOUT & Addr:[6000..7F00] ;

Chip            = Addr:[F800..FB00] ;
A_0             = Addr:[F900] # Addr:[FB00] ;
A_1             = Addr:[FA00..FB00] ;