REM     8 Channel Datalogger program
REM     Written by Thomas Bachmann 07/22/92
REM     Copyright (c) 1992 Blue Earth Research

REM  This program samples 8 analog input channels and logs the data into
REM  the Micro-440's memory.  Channels are sampled 4 times per hour and
REM  averaged so that one data point per hour is stored for each channel.

REM  Data is stored in a contiguous block between 5000H-5FFFH.  This
REM  allows for 4,095 memory locations (data points) which provides 511
REM  hours (about 21 days) of data storage.

REM  A time stamp is placed in memory locations 40E0H-40ECH when the
REM  system begins to collect data, and the memory address of the
REM  beginning data point is stored in memory locations 40EEH & 40EFH.
REM  The memory address of the current data point location is stored in
REM  memory locations 40F0H & 40F1H.  The number of times that the
REM  program stored the beginning data information is stored in memory
REM  location 40F2H.  This can be used to determine if there are any
REM  data gaps due to a power loss.

REM  Other notes:
REM     Write protect the memory, put in the autoexec mode.
REM     Autoexec Mode is implemented by executing the following:
REM   A=6001H:XBY(A+1)=0FFH:XBY(A+2)=0D9H:XBY(A)=0BBH:XBY(A+6)=0DDH


1 REM   Hourly Datalogger

REM Allow for a serial character to terminate the program on power-up.

5   X=0 : G=GET : DO : G=GET : X=X+1 : IF G THEN X=1001
6   WHILE X<1000 : IF G THEN END

REM Initialize system variables and parameters.

10  DIM R(10) : GOTO 200

REM SUBROUTINE TO INCREMENT THE POINTER, VALIDATE IT, AND SAVE IT

12  A=A+CH : IF A<S2 THEN 14 ELSE A=S1
14  XBY(DP)=INT(A/V) : XBY(DP+1)=A.AND.U : RETURN

REM Subroutine to get the data address pointer

20  A=V*XBY(DP)+XBY(DP+1) : RETURN

REM
REM                 MAIN PROGRAM LOOP
REM

30  MIN=0 : HOUR=0 : ONEX1 60

REM PUT IN LOW POWER "WAIT FOREVER" MODE

40  IDLE : GOTO 40

REM First external interrupt, do time stamp and save pointer

60  FOR X=0 TO 12 : XBY(TS+X)=W.AND.XBY(16*X+RTC) : NEXT X
70  XBY(D1)=INT(A/V) : XBY(D1+1)=A.AND.U

REM CHECK IF 15 MINUTES HAVE GONE BY

80  MIN=MIN+1 : IF MIN<15 THEN ONEX1 80 : RETI

REM READ THE DATA AND STORE IT

90  MIN=0 : FOR X=0 TO CH-1

REM Invoke the conversion and read the results

100     XBY(ADC)=X+9 : R(X)=R(X)+XBY(ADC) : NEXT X

REM Set up for next interrupt and loop if not time

110     HOUR=HOUR+1 : IF HOUR<4 THEN ONEX1 80 : RETI

REM Average the results and save to memory

120     HOUR=0 : GOSUB 20 : FOR X=0 TO 6
130     XBY(A+X)=INT(0.5+R(X)/4) : R(X)=0 : NEXT X

REM Set up for next interrupt and loop

140     GOSUB 12 : ONEX1 80 : RETI

REM Define variables for external memory addresses
REM     TS  Points to the time stamp
REM     DP  Points to the next memory location to store data in
REM     RTC Points to the Real Time Clock/Calendar
REM     ADC Points to the Analog to Digital Converter
REM     CH  Is the number of channels to convert and store
REM     Sn  Mark the boundaries of memory for stored data.

200     TS=40E0H : DP=40F0H : D1=40EEH : RTC=0FE00H : IR=0FEE0H
210     ADC=0FF00H : CH=8 : S1=5000H : S2=6000H-CH

REM Other temporary variables:
REM     A   Used to hold data address

220     U=255 : V=256 : W=0FH 

REM Increment power loss counter location

230     XBY(DP+2)=1+XBY(DP+2)

REM Load up and validate the address pointer

250     GOSUB 20 : IF A<S1 THEN 270
260     IF A<S2 THEN 280
270     A=S1 : GOSUB 14

REM Set up the RTC for one minute period interrupts

280     XBY(IR)=8 : GOTO 30