;       File: LCD_P1L.A51       Date: 07/17/92
;
;    /* (c) Copyright BLUE EARTH RESEARCH, MANKATO, MN 1992. */
;    /*                All rights reserved.                  */
;

$ TITLE (4-BIT LCD INTERFACE TO PORT1)
$ DEBUG XREF ERRORPRINT NOGEN
$ DATE (07-17-92)
$ PW(96) PL(60)

;   ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
;   º                                                      º
;   º           LCD MODULE SOFTWARE DRIVER ROUTINE         º
;   º                                                      º
;   ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ

;    ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;    ³            Written By: Thomas Bachmann            ³
;    ³      Blue Earth Research, Mankato, MN  56001      ³
;    ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

; This program implements a 4-bit interface to a LCD module
; using a total of 6 I/O lines on Port1.  Four lines are used
; for data, with two additional controls lines for "Register
; Select" and "E".  The Register Select line is used to specify
; whether data is currently being written to the Command or
; Data register.  The E signal is used to clock the data to the
; LCD module.  A third control line, R/W, is not used in this
; application.  Since data will only be written to the LCD,
; the R/W line is tied low (grounded).

; ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ

$ EJECT

;   ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;   ³      DEFINITIONS SPECIFIC TO THE SYSTEM WIRING      ³
;   ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

; THE FOLLOWING DEFINITIONS ASSUME THAT THE SYSTEM WIRING IS
; CONFIGURED WITH ALL CONNECTIONS TO PORT 1 AS FOLLOWS:

;     SIGNAL            CONTROLLER             SIGNAL
;    --------          ------------           --------
;                 22 ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;      DB4ÄÄÄÄÄÄÄÄÄÄÄ´ P1.0          ³
;                  9 ³               ³
;      DB5ÄÄÄÄÄÄÄÄÄÄÄ´ P1.1          ³
;                 21 ³               ³  +5V ÄÄÄÄÄVcc
;      DB6ÄÄÄÄÄÄÄÄÄÄÄ´ P1.2          ³
;                  8 ³               ³ 1
;      DB7ÄÄÄÄÄÄÄÄÄÄÄ´ P1.3      GND ÃÄÄÄÄÄÄÄÄÄÄÄVee
;                 20 ³               ³ 1
;       RSÄÄÄÄÄÄÄÄÄÄÄ´ P1.4      GND ÃÄÄÄÄÄÄÄÄÄÄÄVss
;                  7 ³               ³ 1
;       E ÄÄÄÄÄÄÄÄÄÄÄ´ P1.5      GND ÃÄÄÄÄÄÄÄÄÄÄÄR/W
;                    ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

; The LCD control lines are wired to the controller as follows:
;   Note: If the Micro-440's 2nd serial port is not being used,
;   the following changes/additions may be made:
;       R_W may optionally be used on P1.6 or P1.7.
;       RS and Eclk may also be reassigned to P1.6 or P1.7.

RS              BIT     P1.4
Eclk            BIT     P1.5

; The following BASIC program can be used to demonstrate the
; functions of the LCD with this program:

;  10    T=100 : C=24 : CALL 7A00H : REM INITIALIZE LCD MODULE
;  30    CALL 7B1EH : REM PRINT SIGN-ON MESSAGE
;  40    FOR R = 1 TO 3 : DBY(C)=0 : REM SET UP CLOCK
;  50    DO : WHILE DBY(C)<T : NEXT R : REM WAIT FOR A WHILE
;  70    CALL 7B23H : REM DISPLAY NEXT MESSAGE
;  80    FOR R = 1 TO 3 : DBY(C)=0 : REM RESET CLOCK
;  90    DO : WHILE DBY(C)<T : NEXT R : REM WAIT FOR A WHILE
;  100   FOR R = 1 TO 3 : CALL 7AEAH : REM SHIFT DISPLAY RIGHT
;  120   DBY(C)=0 : DO : WHILE DBY(C)<T : NEXT R
;  150   DBY(C)=0 : DO : WHILE DBY(C)<T : REM WAIT FOR A WHILE
;  160   FOR R = 1 TO 3 : CALL 7B04H : REM SHIFT DISPLAY LEFT
;  180   DBY(C)=0 : DO : WHILE DBY(C)<T : NEXT R
;  200   DO : A=GET : REM WAIT UNTIL A KEY IS PRESSED
;  210   IF A = 1FH THEN CALL 7B04H : REM LEFT ARROW
;  220   IF A = 14H THEN CALL 7AEAH : REM RIGHT ARROW
;  230   UNTIL A=20H : REM EXIT IF SPACE IS PRESSED
;  240   CALL 7AB2H : CALL 7AC4H : REM CLEAR TIMER0 & SCREEN

;   ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;   ³              DATA MEMORY DECLARATIONS               ³
;   ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

; SEVERAL INTERNAL DATA MEMORY LOCATIONS ARE USED TO STORE
; COUNTERS, POINTERS, ETC. AS FOLLOWS:

                DSEG AT 18H

CLOCK:          DS      1       ; 5 mS Timer
COUNT1:         DS      1
COUNT0:         DS      1
REG_SEL:        DS      1       ; SELECT COMMAND OR DATA REG.
LCD_POINTER:    DS      1       ; POINT TO LAST CHARACTER SENT
TEMP_HOLD:      DS      1       ; LCD BYTE, BUFFER POINTER
STRING_DP:      DS      1       ; HOLD LOW BYTE OF STRING DPTR

                BSEG AT 0

LCD_DATA:       DBIT    1       ; SET WHEN MORE LCD DATA READY
DOING_LCD:      DBIT    1       ; SET WHEN COPYING CHARACTERS

; ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ

INITIALIZE      EQU     7A00H           ; PROGRAM BEGINNING
LCD_BUFFER      EQU     4600H           ; ADDRESS OF LCD BUFFER

ESC             EQU     1BH             ; ESCAPE Character
CLEAR_DISPLAY   EQU     0000$0001B      ; "CLEAR DISPLAY" BYTE
LINE2_0         EQU     1100$0000B      ; "GOTO LINE 2" BYTE
LINE1_0         EQU     1000$0000B      ; "GOTO LINE 1" BYTE

EXEC_TIME       EQU     60              ; EXECUTION TIME
                                        ;  FOR INSTRUCTIONS

RESET           EQU     1100$0011B      ; "RESET" BYTE

F_FIRST         EQU     1100$0010B      ; "FUNCTION SET" BYTES
F_SET           EQU     0010$1000B      ; "FUNCTION SET" BYTES
DOFF            EQU     0000$1000B      ; "DISPLAY OFF" BYTES
DON             EQU     0000$1100B      ; "DISPLAY ON" BYTES

;       NOTE: 0000$11cbB For "Display On," where
;             c=1 for Cursor on, and b=1 for blinking character

MODE            EQU     0000$0110B      ; "ENTRY MODE" BYTES
SHIFTR          EQU     0001$1100B      ; "SHIFT RIGHT" BYTES
SHIFTL          EQU     0001$1000B      ; "SHIFT LEFT" BYTES

$ EJECT

; ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ

;      ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;      ³         MACRO FOR SENDING A CHARACTER        ³
;      ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

; THIS MACRO IS USED THROUGHOUT THE SOURCE FILE TO SEND A
; 4-BIT CHARACTER (COMMAND) TO THE LCD.

; THE MACRO PARAMETERS ARE AS FOLLOWS:

;       WORD = THE NAME OF THE CHARACTER TO SEND

; IF THE 'NOGEN' CONTROL IS SPECIFIED IN THE SOURCE FILE,
; ONLY THE MACRO CALL THAT APPEARS IN THE SOURCE FILE IS
; INCLUDED IN THE LIST FILE.  IF THE 'NOGEN' CONTROL IS NOT 
; SPECIFIED, OR IF THE 'GEN' CONTROL IS SPECIFIED, THE MACRO 
; IS SHOWN FULLY EXPANDED IN THE LIST FILE.

; THE DOUBLE SEMICOLONS ARE USED TO PREVENT THE COMMENTS FROM
; BEING INCLUDED IN THE MACRO EXPANSION IN THE LIST FILE.

OUTPUT  MACRO   WORD
        MOV     A,#WORD         ;; GET OUTPUT BYTE
        MOV     TEMP_HOLD,A     ;; SAVE IT
        SWAP    A
        ANL     A,#0FH          ;; GET RID OF LOWER HALF
        ORL     A,#0C0H         ;; ALLOW SERIAL PRINTER
        MOV     P1,A
        SETB    Eclk
        CLR     Eclk
        MOV     A,TEMP_HOLD     ;; GET OUTPUT BYTE AGAIN
        ANL     A,#0FH          ;; MASK UPPER HALF
        ORL     A,#0C0H         ;; ALLOW SERIAL PRINTER
        MOV     P1,A
        ACALL   CLOCK_N_WAIT
        ENDM

; ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ

$ EJECT

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³        BEGINNING OF INITIALIZATION ROUTINE          ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

                CSEG AT INITIALIZE

        CLR     A
        MOV     LCD_POINTER,A   ; NO CHARS IN BUFFER
        MOV     STRING_DP,A
        CLR     LCD_DATA        ; NO CHARS READY FOR LCD
        CLR     DOING_LCD       ; NOT DOING LCD NOW

        MOV     DPTR,#400BH     ; Stuff "LJMP XXXXH" into
        MOV     A,#2            ;  mirrored Timer 0 overflow
        MOVX    @DPTR,A         ;  vector at address 400BH.

        INC     DPTR
        MOV     A,#HIGH Timer0Int  ; Location of Timer 0
        MOVX    @DPTR,A         ;  interrupt routine.

        INC     DPTR
        MOV     A,#LOW Timer0Int
        MOVX    @DPTR,A

; ------------------- INITIALIZE LCD MODULE -------------------

START:  CLR     Eclk

        MOV     COUNT1,#0FFH            ; WAIT FOR A LONG TIME
        ACALL   WAIT_Z

        MOV     P1,#RESET               ; WRITE BYTE
        SETB    Eclk                    ; CLOCK IT IN
        CLR     Eclk

        MOV     COUNT1,#9               ; WAIT AT LEAST 4.1 mS
        ACALL   WAIT_Z

        MOV     P1,#RESET               ; WRITE BYTE
        ACALL   CLOCK_N_WAIT

        MOV     P1,#RESET               ; WRITE BYTE
        ACALL   CLOCK_N_WAIT

        MOV     P1,#F_FIRST             ; WRITE BYTE
        ACALL   CLOCK_N_WAIT            ; CLOCK IT IN

OUTPUT  F_SET                           ; FUNCTION SET
OUTPUT  DOFF                            ; TURN DISPLAY OFF
        ACALL   CLEAR                   ; CLEAR DISPLAY
OUTPUT  MODE                            ; SET ENTRY MODE
OUTPUT  DON                             ; TURN DISPLAY ON

; ------------- SET UP TIMER0 FOR 5 mS INTERRUPT --------------

        MOV     A,TL0           ; Reload Timer 0 for 5 mS
        ADD     A,#LOW -4998    ; (Less 2uS to compensate
        MOV     TL0,A           ; for ADD & MOV latency.)
        MOV     TH0,#HIGH -4998

; Timer 0 is a 16 bit timer used to generate a 5 mS interrupt.
; The input to both Timers is the internal system clock
; The frequency is OSC/12 = 1 MHz. (1uS)

;       TMOD:
;                Timer 1                     Timer 0
;     ÃÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÅÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄ´
;     ³ GAT  ³ C/T  ³  M1  ³  M0  ³ GAT  ³ C/T  ³  M1  ³  M0  ³
;     ÀÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÙ
;        0      0      0      1      0      0      0      1

        MOV     TMOD,#11H       ; TIMER/CNTR MODE CTRL REGISTER

;       TCON:
;     ÚÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄ¿
;     ³ TF1  ³ TR1  ³ TF0  ³ TR0  ³ IE1  ³ IT1  ³ IE0  ³ IT0  ³
;     ÀÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÙ
;        0      0      0      1      0      0      0      0

        SETB    TR0             ; Start Timer

;       IE:
;     ÚÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄ¿
;     ³  EA  ³  EC  ³ ET2  ³  ES  ³ ET1  ³ EX1  ³ ET0  ³ EX0  ³
;     ÀÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÙ
;        1      0      0      0      0      0      1      0

        SETB    ET0             ; Timer 0 interrupt enable
        SETB    EA              ; Global interrupt enable

        RET

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³                  CLEAR TIMER0 INTERRUPT                 ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

STOP:   CLR     TR0             ; Stop Timer
        CLR     ET0             ; Timer 0 interrupt enable
        CLR     EA              ; Global interrupt enable
        RET

$ EJECT

;   ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;   ³              DISPLAY WRITING SUBROUTINES            ³
;   ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

CLOCK_N_WAIT:
        SETB    Eclk                    ; CLOCK IN THE BYTE
        CLR     Eclk
        MOV     COUNT0,#EXEC_TIME       ; WAIT AT LEAST 120 uS
        DJNZ    COUNT0,$
        RET

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³                    CLEAR DISPLAY                    ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

CLEAR:  OUTPUT  CLEAR_DISPLAY
        MOV     COUNT1,#10              ; WAIT AT LEAST 4.9 mS

WAIT_Z: MOV     COUNT0,#0FFH
        DJNZ    COUNT0,$
        DJNZ    COUNT1,WAIT_Z
        RET

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³                SCROLL MESSAGE RIGHT                 ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

SCROLL_RIGHT:   OUTPUT  SHIFTR
        RET                     ; BACK TO BASIC

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³                SCROLL MESSAGE LEFT                  ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

SCROLL_LEFT:    OUTPUT  SHIFTL
        RET                     ; BACK TO BASIC

$ EJECT

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³              DISPLAY SYSTEM MESSAGES                ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

; Note that these lines may be duplicated for adding other
;  messages that are to be displayed.

STR1:   MOV     DPTR,#MSG1      ; SIGN ON MESSAGE
        SJMP    DUPE_STRING

STR2:   MOV     DPTR,#MSG2      ; DEMO DISPLAY MESSAGE
        SJMP    DUPE_STRING

STR3:   MOV     DPTR,#MSG3      ; NEXT DISPLAY MESSAGE
        SJMP    DUPE_STRING

STR4:   MOV     DPTR,#MSG4      ; NEXT DISPLAY MESSAGE
        SJMP    DUPE_STRING

STR5:   MOV     DPTR,#MSG5      ; NEXT DISPLAY MESSAGE
        SJMP    DUPE_STRING

STR6:   MOV     DPTR,#MSG6      ; NEXT DISPLAY MESSAGE

; COPY THE SPECIFIED CHARACTER STRING TO THE LCD OUTPUT BUFFER.

DUPE_STRING:
        SETB    DOING_LCD       ; NO INTERRUPTS
        MOV     STRING_DP,DPL   ; SAVE LAST STRING OUTPUT
        JNB     LCD_DATA,LOAD_IT  ; NO CHARS WAITING

; THERE ARE CHARACTERS WAITING TO BE SENT TO THE LCD - CHECK
;  IF THE FIRST CHARACTERS ARE AN <ESC> AND CLEAR_DISPLAY

        MOVX    A,@DPTR         ; GET FIRST BYTE
        CJNE    A,#ESC,FIND_END ; NOT A ZERO

        INC     DPTR            ; POINT TO INSTRUCTION BYTE
        MOVX    A,@DPTR

        XCH     A,DPL           ; DECREMENT THE DPTR
        JNZ     DECDP
        DEC     DPH

DECDP:  DEC     A
        XCH     A,DPL

        CJNE    A,#CLEAR_DISPLAY,FIND_END

$ EJECT

LOAD_IT:
        PUSH    DPH
        PUSH    DPL
        MOV     DPTR,#LCD_BUFFER
        MOV     DPL,LCD_POINTER
        INC     DPL
        MOV     TEMP_HOLD,DPL   ; SAVE THE LCD BUFFER POINTER

NEXT_CHAR:
        POP     DPL
        POP     DPH
        MOVX    A,@DPTR         ; GET NEXT CHAR TO SEND
        CJNE    A,#'"',MORE_CHARS
        SJMP    ONE_MORE

MORE_CHARS:
        INC     DPTR            ; SET UP FOR NEXT CHARACTER
        PUSH    DPH
        PUSH    DPL

ONE_MORE:
        MOV     DPTR,#LCD_BUFFER
        MOV     DPL,TEMP_HOLD
        MOVX    @DPTR,A
        INC     TEMP_HOLD
        CJNE    A,#'"',NEXT_CHAR

        SETB    LCD_DATA        ; CHARS READY FOR LCD
        CLR     DOING_LCD
        RET

FIND_END:       ; FIND THE LAST CHARACTER IN THE OUTPUT BUFFER
        PUSH    DPH
        PUSH    DPL
        MOV     DPTR,#LCD_BUFFER
        MOV     DPL,LCD_POINTER  ; LOAD THE CURRENT POINTER

GET_END_CHAR:
        INC     DPL
        MOVX    A,@DPTR
        CJNE    A,#'"',GET_END_CHAR

; FOUND THE END OF THE OUTPUT BUFFER

        MOV     TEMP_HOLD,DPL   ; SAVE THE LCD BUFFER POINTER
        SJMP    NEXT_CHAR

$ EJECT

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³            TIMER0 INTERRUPT SERVICING ROUTINE           ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

Timer0Int:
        PUSH    ACC             ; 5 mS interrupt
        PUSH    PSW
        PUSH    DPH
        PUSH    DPL

        MOV     A,TL0           ; Reload Timer 0 for 5 mS
        ADD     A,#LOW -4998    ; (Less 2uS to compensate
        MOV     TL0,A           ; for ADD & MOV latency.)
        MOV     TH0,#HIGH -4998

        INC     CLOCK           ; UPDATE TIMER FOR BASIC

; ---------------------- LCD UPDATE ---------------------------

DO_LCD: JB      DOING_LCD,TIME1  ; Wait until next loop
        JNB     LCD_DATA,TIME1  ; Check for LCD Chars

        MOV     DPTR,#LCD_BUFFER  ; POINT TO BUFFER
        INC     LCD_POINTER     ; POINT TO NEXT CHARACTER
        MOV     DPL,LCD_POINTER
        MOVX    A,@DPTR         ; GET IT
        CJNE    A,#'"',VALID_CHAR  ; DONE YET?

        CLR     LCD_DATA        ; NO MORE CHARACTERS NOW
        SJMP    TIME1

VALID_CHAR:
        MOV     REG_SEL,#0D0H   ; POINT TO DATA REGISTER
        CJNE    A,#ESC,WRITE_DATA  ; CONTROL CHARACTER?

        MOV     REG_SEL,#0C0H   ; OUTPUT TO COMMAND REGISTER
        INC     LCD_POINTER
        MOV     DPL,LCD_POINTER
        MOVX    A,@DPTR         ; GET IT

WRITE_DATA:
        MOV     TEMP_HOLD,A     ; SAVE IT

$ EJECT

; ------------------ OUTPUT CHARACTER HALF --------------------

        SWAP    A
        ANL     A,#0FH          ; GET RID OF LOWER HALF
        ORL     A,REG_SEL       ; SELECT COMMAND OR DATA
        MOV     P1,A
        SETB    Eclk
        CLR     Eclk

        MOV     A,TEMP_HOLD     ; GET LOWER HALF

        ANL     A,#0FH          ; OUTPUT OTHER CHAR HALF
        ORL     A,REG_SEL       ; SELECT COMMAND OR DATA
        MOV     P1,A
        SETB    Eclk
        CLR     Eclk

TIME1:

;*      Any other function that needs to be executed every   *;
;*      5 mS should be programmed here.                      *;

AllDone:
        POP     DPL             ; Tail end of 5 mS interrupt
        POP     DPH
        POP     PSW
        POP     ACC
        RETI

$ EJECT

;   ÕÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ͸
;   ³            CHARACTER STRING DEFINITIONS             ³
;   ÔÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ;

MSG1:           DB      'Blue Earth'
                DB      ESC,LINE2_0,'Research"'

MSG2:           DB      ESC,CLEAR_DISPLAY,'  Micro-440'
                DB      ESC,LINE2_0,'Demonstration"'

MSG3:           DB      ESC,CLEAR_DISPLAY,'Thomas Bachmann'
                DB      ESC,LINE2_0,'Programmer"'

MSG4:           DB      ESC,CLEAR_DISPLAY,'  Put YOUR'
                DB      ESC,LINE2_0,'Message HERE"'

MSG5:           ; Any number of messages may be placed here for
MSG6:           ;  displaying on the LCD.  Note that commands
MSG7:           ;  are preceeded by an ESC, and each message
MSG8:           ;  must end with a quote character (").
MSG9:

                                ; END OF PROGRAM
        END


; Following is the HEX file derived from the assembled source
; file.  This can be used for directly loading the program via
; MONITOR-51 and almost any terminal program.

:107A0000E4F51CF51EC200C20190400B7402F0A305
:107A1000747BF0A37498F0C2957519FF51E07590CE
:107A2000C3D295C29575190951E07590C351B975C6
:107A300090C351B97590C251B97428F51DC4540F43
:107A400044C0F590D295C295E51D540F44C0F59001
:107A500051B97408F51DC4540F44C0F590D295C2B5
:107A600095E51D540F44C0F59051B951C47406F505
:107A70001DC4540F44C0F590D295C295E51D540F16
:107A800044C0F59051B9740CF51DC4540F44C0F5B1
:107A900090D295C295E51D540F44C0F59051B9E5BB
:107AA0008A247AF58A758CEC758911D28CD2A9D288
:107AB000AF22C28CC2A9C2AF22D295C295751A3C20
:107AC000D51AFD227401F51DC4540F44C0F590D29F
:107AD00095C295E51D540F44C0F59051B975190A2A
:107AE000751AFFD51AFDD519F722741CF51DC4545B
:107AF0000F44C0F590D295C295E51D540F44C0F5D2
:107B00009051B9227418F51DC4540F44C0F590D299
:107B100095C295E51D540F44C0F59051B922907B54
:107B2000F28017907C078012907C24800D907C421C
:107B30008008907C5D8003907C5DD20185821E3040
:107B40000012E0B41B3DA3E0C5827002158314C58A
:107B500082B4012FC083C082904600851C820582BA
:107B600085821DD082D083E0B422028005A3C08329
:107B7000C082904600851D82F0051DB422E5D2002A
:107B8000C20122C083C082904600851C820582E02B
:107B9000B422FA85821D80CBC0E0C0D0C083C082F1
:107BA000E58A247AF58A758CEC051820013B3000B3
:107BB00038904600051C851C82E0B42204C2008077
:107BC00028751BD0B41B09751BC0051C851C82E0E1
:107BD000F51DC4540F451BF590D295C295E51D5473
:107BE0000F451BF590D295C295D082D083D0D0D0CE
:107BF000E032426C75652045617274681BC0526545
:107C0000736561726368221B0120204D6963726F86
:107C10002D3434301BC044656D6F6E7374726174A3
:107C2000696F6E221B0154686F6D6173204261633E
:107C3000686D616E6E1BC050726F6772616D6D65AD
:107C400072221B01202050757420594F55521BC0C1
:0D7C50004D657373616765204845524522FC
:00000001FF


; Following is the HEX file derived from loading the BASIC
; program to the controller's ROMsim Memory.  Note that the
; REM statements have been removed from the program lines.

:106008005512000194204C4344204F4E20504F52CB
:1060180054310D15000A54EA3130303A43EA32342B
:106028003A8837413030480D0A001E8837423145DA
:10603800480D1100289E52EA31A4333ABAE04329A8
:10604800EA300D100032923A9FBAE04329EE543AF2
:1060580095520D0A00468837423233480D110050D8
:106068009E52EA31A4333ABAE04329EA300D1000CF
:106078005A923A9FBAE04329EE543A95520D1100CC
:10608800649E52EA31A4333A8837414541480D1796
:106098000078BAE04329EA303A923A9FBAE04329B5
:1060A800EE543A95520D140096BAE04329EA303A74
:1060B800923A9FBAE04329EE540D1100A09E52EA8D
:1060C80031A4333A8837423034480D1700B4BAE067
:1060D8004329EA303A923A9FBAE04329EE543A9576
:1060E800520D0900C8923A41EABE0D1100D29C41F6
:1060F800EA314648A38837423034480D1100DC9C09
:1061080041EA313448A38837414541480D0A00E641
:10611800A041EA3230480D1100F088374142324838
:0A6128003A8837414334480D010165
:00000001FF