REM            File: PCA_PWM.BAS      Date: 09/08/92
REM
REM  /* (c) Copyright BLUE EARTH RESEARCH, MANKATO, MN 1992. */
REM  /*                All rights reserved.                  */
REM

REM   ΙΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝ»
REM   Ί             GENERATE PWM USING THE PCA              Ί
REM   ΘΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΌ

REM    ΥΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΈ
REM    ³            Written By: Thomas Bachmann            ³
REM    ³      Blue Earth Research, Mankato, MN  56001      ³
REM    ΤΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΝΎ

REM  NOTES:
REM    This program generates a PWM output on P1.3 using the PCA.
REM    The Duty Cycle is based on the analog input to ADC channel 8,
REM    which is connected to the Application Module's potentiometer.

REM    The PWM frequency is determined by the TIMER0 counter overflow.
REM    The period is adjustable in increments of 256 microseconds.
REM    The program automatically figures out the closest frequency to
REM    the specified value.

1 REM PCA PWM Program

REM     Initialize program variables
10  ADC=0FF00H : CH=15 : V=256

REM     Get input to specify desired frequency
20  PRINT : INPUT "Enter Output Frequency ", FREQ

30  IF ((7800<FREQ).OR.(FREQ<15.3)) THEN PRINT CHR$(7), : GOTO 20

REM     Calculate TIMER0 Reload Value
40  P=INT(0.5+1E+6/(FREQ*256)) : RL=V*(V-P)+V-P : FREQ=1E+6/(P*256)

REM     Display calculated value and verify
60  PRINT U.(####.#), "Actual frequency is", FREQ, "Hz"
70  PRINT : PRINT "Press any key to begin (SPACE to abort)"

80  DO : G=GET : UNTIL G : IF G=20H THEN 20

REM     Initialize Timer0 registers as 8-Bit Auto-Reload
90  TMOD=12H : TIMER0=RL : TCON=TCON.OR.10H

REM     Get initial value for duty cycle
100 XBY(ADC)=CH : R=XBY(ADC) : CCAP0=V*(V-R)+V-R

REM     Initialize the PCA registers for the PWM mode
110 PCA=0 : CMOD=4 : CCAPM0=42H : CCON=40H

REM     Read ADC channel 8 and invert the result
120 XBY(ADC)=CH : R=255-XBY(ADC)

REM     Update the duty cycle
REM     Read the low byte and write the new value to the high byte
130 A=0FFH.AND.CCAP0 : CCAP0=A+V*R

REM     Check if SPACE has been pressed yet
140 G=GET : IF G=20H THEN CCAPM0=0 : GOTO 20 ELSE 120